{
  self,
  flake-utils,
  nixng,
  nginx,
  blog,
  nixpkgs,
  nixpkgs-bazarr,
  nixpkgs-radicale,
  nixpkgs-master,
  ...
}:
flake-utils.lib.eachDefaultSystem (system: let
  images = {
    dnsmasq = ./dnsmasq.nix;
    attic = ./attic.nix;
    ntfy = ./ntfy.nix;
    radicale = ./radicale.nix;
    jellyseerr = ./jellyseerr.nix;
    radarr = ./radarr.nix;
    sonarr = ./sonarr.nix;
    bazarr = ./bazarr.nix;
    prowlarr = ./prowlarr.nix;
    blog = ./blog.nix;
  };
in {
  nixngConfigurations = builtins.mapAttrs (name: configFile:
    nixng.nglib.makeSystem {
      inherit nixpkgs system;
      name = "nixng-${name}";
      config = import configFile;

      specialArgs = {
        inherit nginx blog;
        inherit (self) globals;
      };

      extraModules = [
        self.nixngModules.bazarr
        self.nixngModules.radicale
        self.nixngModules.jellyseerr
        self.nixngModules.radarr
        self.nixngModules.sonarr
        self.nixngModules.prowlarr
        {
          nixpkgs.overlays = [
            (final: _prev: {
              # From master branch
              prowlarr = nixpkgs-master.legacyPackages.${system}.prowlarr;
              jellyseerr = nixpkgs-master.legacyPackages.${system}.jellyseerr;

              # From forks
              bazarr = nixpkgs-bazarr.legacyPackages.${system}.bazarr;
              radicale = nixpkgs-radicale.legacyPackages.${system}.radicale;
            })
          ];
        }
      ];
    })
  images;
})