nixos-servers/nixos/machines/default.nix

{ lib, ... }:
let
  machineOpts = { ... }: {
    options = {
      # TODO: rename to kind?
      kind = lib.mkOption {
        type = lib.types.enum [ "physical" "virtual" ];
        description = ''
          Whether this machine is physical or virtual.
        '';
      };

      hypervisorName = lib.mkOption {
        default = null;
        type = with lib.types; nullOr str;
        description = ''
          The host name of the hypervisor hosting this virtual machine.
        '';
      };

      arch = lib.mkOption {
        default = null;
        type = with lib.types; nullOr str;
        description = ''
          CPU architecture of this machine.
        '';
      };

      isRaspberryPi = lib.mkOption {
        default = false;
        type = lib.types.bool;
      };

      isHypervisor = lib.mkOption {
        default = false;
        type = lib.types.bool;
      };

      nixosModule = lib.mkOption {
        default = { ... }: { };
        type = lib.types.anything;
        description = ''
          Customized configuration for this machine in the form of a NixOS module.
        '';
      };
    };
  };
in
{
  options = {
    machines = lib.mkOption {
      type = with lib.types; attrsOf (submodule machineOpts);
    };
  };

  config = {
    machines = {
      warwick = {
        kind = "physical";
        arch = "aarch64-linux";
        isRaspberryPi = true;

        nixosModule.lab = {
          storage = {
            osDisk = "/dev/sda";
          };
        };
      };

      atlas = {
        kind = "physical";
        arch = "x86_64-linux";
        isHypervisor = true;

        nixosModule.lab = {
          storage = {
            osDisk = "/dev/sda";
            dataPartition = "/dev/nvme0n1p1";
          };

          ssh = {
            useCertificates = true;
            hostCert = builtins.readFile ./certificates/atlas/host_ed25519.crt;
            userCert = builtins.readFile ./certificates/atlas/user_ed25519.crt;
          };
        };
      };

      jefke = {
        kind = "physical";
        arch = "x86_64-linux";
        isHypervisor = true;

        nixosModule.lab = {
          storage = {
            osDisk = "/dev/sda";
            dataPartition = "/dev/nvme0n1p1";
          };

          ssh = {
            useCertificates = true;
            hostCert = builtins.readFile ./certificates/jefke/host_ed25519.crt;
            userCert = builtins.readFile ./certificates/jefke/user_ed25519.crt;
          };
        };
      };

      lewis = {
        kind = "physical";
        arch = "x86_64-linux";
        isHypervisor = true;

        nixosModule.lab = {
          backups.enable = true;
          data-sharing.enable = true;
          networking.dmz.allowConnectivity = true;

          storage = {
            osDisk = "/dev/sda";
            dataPartition = "/dev/nvme0n1p1";
          };

          ssh = {
            useCertificates = true;
            hostCert = builtins.readFile ./certificates/lewis/host_ed25519.crt;
            userCert = builtins.readFile ./certificates/lewis/user_ed25519.crt;
          };
        };
      };

      hermes = {
        kind = "virtual";
        hypervisorName = "lewis";

        nixosModule = { hypervisorConfig, ... }: {
          lab = {
            networking = {
              dmz.services.enable = true;
              staticNetworking = true;
              staticIPv4 = hypervisorConfig.lab.networking.dmz.ipv4.services;
              staticIPv6 = hypervisorConfig.lab.networking.dmz.ipv6.services;
            };

            vm = {
              # TODO: would be cool to create a check that a mac address is only ever assigned to one VM.
              # TODO: idea: what if we generated these IDs by hashing the host name and reducing that to the amount of hosts possible?
              id = 7;

              shares = [{
                name = "dnsmasq";
                mountPoint = "/var/lib/dnsmasq";
              }];
            };
          };
        };
      };

      maestro = {
        kind = "virtual";
        hypervisorName = "atlas";

        nixosModule = { config, ... }: {
          microvm.balloonMem = 7680;

          lab = {
            dockerSwarm.enable = true;

            vm = {
              id = 1;
            };
          };
        };
      };

      bancomart = {
        kind = "virtual";
        hypervisorName = "jefke";

        nixosModule = {
          microvm.balloonMem = 7680;

          lab = {
            dockerSwarm.enable = true;
            vm.id = 2;
          };
        };
      };

      vpay = {
        kind = "virtual";
        hypervisorName = "lewis";

        nixosModule = {
          microvm.balloonMem = 5120;

          lab = {
            dockerSwarm.enable = true;
            vm.id = 3;
          };
        };
      };
    };
  };
}