nixos-servers/flake.nix

{
  description = "NixOS definitions for our home servers";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-23.11";
    nixpkgs-unstable.url = "github:pizzapim/nixpkgs/gatus";
    deploy-rs.url = "github:serokell/deploy-rs";
    nixos-hardware.url = "github:NixOS/nixos-hardware/master";
    flake-utils.url = "github:numtide/flake-utils";

    disko = {
      url = "github:nix-community/disko";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    agenix = {
      url = "github:ryantm/agenix";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    dns = {
      url = "github:kirelagin/dns.nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    kubenix = {
      url = "github:pizzapim/kubenix/servers";
      # url = "file:///home/pim/git/forks/kubenix";
      # type = "git";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    nixhelm = {
      url = "github:farcaller/nixhelm";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    blog-pim = {
      url = "git+https://git.kun.is/home/blog-pim";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    inputs@{ self, nixpkgs, flake-utils, ... }:
    let
      system = "x86_64-linux";
      pkgs = import nixpkgs { inherit system; };
      machines = (pkgs.lib.modules.evalModules { modules = [ (import ./machines) ]; }).config.machines;
      myLib = import ./my-lib pkgs.lib;
    in
    flake-utils.lib.meld (inputs // { inherit pkgs machines myLib; }) [
      ./flake-parts/scripts
      ./flake-parts/checks.nix
      ./flake-parts/deploy.nix
      ./flake-parts/nixos.nix
      ./flake-parts/kubenix.nix
    ] // (flake-utils.lib.eachDefaultSystem (system: {
      formatter = nixpkgs.legacyPackages.${system}.nixfmt;
    }));
}