create shared entrypoint nixos config for physical and vm

nixos/modules/networking/dmz/default.nix

@@ -0,0 +1,68 @@
+{ pkgs, lib, config, dns, ... }@inputs:
+let
+  cfg = config.lab.networking.dmzServices;
+  kunisZoneFile = pkgs.writeTextFile {
+    name = "kunis-zone-file";
+    text = (dns.lib.toString "kun.is" (import ./zones/kun.is.nix inputs));
+  };
+
+  geokunis2nlZoneFile = pkgs.writeTextFile {
+    name = "geokunis2nl-zone-file";
+    text = (dns.lib.toString "geokunis2.nl" (import ./zones/geokunis2.nl.nix inputs));
+  };
+in
+{
+  options.lab.networking.dmzServices.enable = lib.mkOption {
+    default = false;
+    type = lib.types.bool;
+    description = ''
+      Whether to enable an authoritative DNS server and DNSmasq for DMZ network.
+    '';
+  };
+
+  config = lib.mkIf cfg.enable {
+    lab.networking.allowDMZConnectivity = true;
+
+    networking.firewall.interfaces.${config.lab.networking.dmzBridgeName} = {
+      allowedTCPPorts = [ 53 5353 ];
+      allowedUDPPorts = [ 53 67 5353 ];
+    };
+
+    services = {
+      bind = {
+        enable = true;
+        forwarders = [ ];
+
+        extraOptions = ''
+          allow-transfer { none; };
+          allow-recursion { none; };
+          version none;
+          notify no;
+        '';
+
+        zones = {
+          "kun.is" = {
+            master = true;
+            file = kunisZoneFile;
+            allowQuery = [ "any" ];
+          };
+
+          "geokunis2.nl" = {
+            master = true;
+            file = geokunis2nlZoneFile;
+            allowQuery = [ "any" ];
+            slaves = [
+              "87.253.155.96/27"
+              "157.97.168.160/27"
+            ];
+          };
+        };
+      };
+
+      dnsmasq = {
+        enable = true;
+        settings = import ./dnsmasq.nix inputs;
+      };
+    };
+  };
+}

nixos/modules/networking/dmz/dnsmasq.nix

@@ -0,0 +1,50 @@
+{ config, ... }:
+let
+  inherit (config.lab.networking) publicIPv4 dockerSwarmInternalIPv4 dmzServicesIPv4 dmzServicesIPv6 dmzRouterIPv4;
+in
+{
+  no-resolv = true;
+  local = "/dmz/";
+  dhcp-fqdn = true;
+  no-hosts = true;
+  expand-hosts = true;
+  domain = "dmz";
+  dhcp-authoritative = true;
+  ra-param = "*,0,0";
+  alias = "${publicIPv4},${dockerSwarmInternalIPv4}";
+  log-dhcp = true;
+  log-queries = true;
+  port = "5353";
+  host-record = [
+    "hermes.dmz,${dmzServicesIPv4},${dmzServicesIPv6}"
+    "ipv4.hermes.dmz,${dmzServicesIPv4}"
+    "ipv6.hermes.dmz,${dmzServicesIPv6}"
+  ];
+
+  server = [
+    dmzRouterIPv4
+    "/geokunis2.nl/${dmzServicesIPv4}"
+    "/kun.is/${dmzServicesIPv4}"
+  ];
+
+  dhcp-range = [
+    "192.168.30.50,192.168.30.127,15m"
+    "2a0d:6e00:1a77:30::,ra-stateless,ra-names"
+  ];
+
+  dhcp-host = [
+    "b8:27:eb:b9:ab:e2,esrom"
+    "ca:fe:c0:ff:ee:08,maestro,${dockerSwarmInternalIPv4}"
+  ];
+
+  dhcp-option = [
+    "3,${dmzRouterIPv4}"
+    "option:dns-server,${dmzRouterIPv4}"
+    "option6:dns-server,[2a02:58:19a:30::1]"
+  ];
+
+  address = [
+    "/ns.pizzapim.nl/ns.geokunis2.nl/${dmzServicesIPv4}"
+    "/ns.pizzapim.nl/ns.geokunis2.nl/${dmzServicesIPv6}"
+  ];
+}

nixos/modules/networking/dmz/zones/geokunis2.nl.nix

@@ -0,0 +1,68 @@
+{ config, dns, ... }:
+with dns.lib.combinators;
+let
+  inherit (config.lab.networking) publicIPv4 dmzServicesIPv6 dockerSwarmIPv6;
+in
+{
+  SOA = {
+    nameServer = "ns";
+    adminEmail = "hostmaster@geokunis2.nl";
+    serial = 2024011401;
+  };
+
+  NS = [
+    "ns.geokunis2.nl."
+    "ns0.transip.net."
+    "ns1.transip.nl."
+    "ns2.transip.eu."
+  ];
+
+  MX = [ (mx.mx 10 "mail.geokunis2.nl.") ];
+
+  A = [ publicIPv4 ];
+  AAAA = [ dockerSwarmIPv6 ];
+  CAA = letsEncrypt "caa@geokunis2.nl";
+
+  subdomains = {
+    "*" = {
+      A = [ publicIPv4 ];
+      AAAA = [ dockerSwarmIPv6 ];
+    };
+
+    ns = {
+      A = [ publicIPv4 ];
+      AAAA = [ dmzServicesIPv6 ];
+    };
+
+    ns1 = {
+      A = [ publicIPv4 ];
+      AAAA = [ dmzServicesIPv6 ];
+    };
+
+    ns2 = {
+      A = [ publicIPv4 ];
+      AAAA = [ dmzServicesIPv6 ];
+    };
+
+    # Override because we don't support IPv6 for KMS.
+    kms = {
+      A = [ publicIPv4 ];
+      AAAA = [ ];
+    };
+
+    wg = {
+      A = [ publicIPv4 ];
+      AAAA = [ "2a0d:6e00:1a77::1" ];
+    };
+
+    wg4 = {
+      A = [ publicIPv4 ];
+      AAAA = [ ];
+    };
+
+    wg6 = {
+      A = [ ];
+      AAAA = [ "2a0d:6e00:1a77::1" ];
+    };
+  };
+}

nixos/modules/networking/dmz/zones/kun.is.nix

@@ -0,0 +1,64 @@
+{ config, dns, ... }:
+with dns.lib.combinators;
+let
+  inherit (config.lab.networking) publicIPv4 dmzServicesIPv6 dockerSwarmIPv6;
+in
+{
+  CAA = letsEncrypt "caa@kun.is";
+
+  SOA = {
+    nameServer = "ns1";
+    adminEmail = "webmaster@kun.is";
+    serial = 2024011401;
+  };
+
+  NS = [
+    "ns1.kun.is."
+    "ns2.kun.is."
+  ];
+
+  MX = [
+    (mx.mx 10 "mail.kun.is.")
+  ];
+
+  subdomains = {
+    "*" = {
+      A = [ publicIPv4 ];
+      AAAA = [ dockerSwarmIPv6 ];
+    };
+
+    ns = {
+      A = [ publicIPv4 ];
+      AAAA = [ dmzServicesIPv6 ];
+    };
+
+    ns1 = {
+      A = [ publicIPv4 ];
+      AAAA = [ dmzServicesIPv6 ];
+    };
+
+    ns2 = {
+      A = [ publicIPv4 ];
+      AAAA = [ dmzServicesIPv6 ];
+    };
+
+    # Override because we don't support IPv6 for Git SSH.
+    git = {
+      A = [ publicIPv4 ];
+      AAAA = [ ];
+    };
+
+    # Override because we don't support IPv6 for KMS.
+    kms = {
+      A = [ publicIPv4 ];
+      AAAA = [ ];
+    };
+
+    # Override because wg is on opnsense so ipv6 differs from "dmzServicesIPv6"
+    wg = {
+      A = [ publicIPv4 ];
+      AAAA = [ "2a0d:6e00:1a77::1" ];
+    };
+
+  };
+}