change networking config structuring

nixos/modules/networking/dmz_services/default.nix

@@ -0,0 +1,73 @@
+# TODO: we should split this into DHCP and DNS
+# This decoupling makes it easier to put one service on another host.
+{ pkgs, lib, config, dns, ... }@inputs:
+let
+  cfg = config.lab.networking.dmz.services;
+
+  kunisZoneFile = pkgs.writeTextFile {
+    name = "kunis-zone-file";
+    text = (dns.lib.toString "kun.is" (import ./zones/kun.is.nix inputs));
+  };
+
+  geokunis2nlZoneFile = pkgs.writeTextFile {
+    name = "geokunis2nl-zone-file";
+    text = (dns.lib.toString "geokunis2.nl" (import ./zones/geokunis2.nl.nix inputs));
+  };
+in
+{
+  options.lab.networking.dmz.services.enable = lib.mkOption {
+    default = false;
+    type = lib.types.bool;
+    description = ''
+      Whether to enable an authoritative DNS server and DNSmasq for DMZ network.
+    '';
+  };
+
+  config = lib.mkIf cfg.enable {
+    # TODO Remove this; make this explicit in the machine config.
+    lab.networking.dmz.allowConnectivity = true;
+
+    # TODO: listen only on dmz interface, make this portable between physical and VM.
+    networking.firewall = {
+      allowedTCPPorts = [ 53 5353 ];
+      allowedUDPPorts = [ 53 67 5353 ];
+    };
+
+    services = {
+      bind = {
+        enable = true;
+        forwarders = [ ];
+
+        extraOptions = ''
+          allow-transfer { none; };
+          allow-recursion { none; };
+          version none;
+          notify no;
+        '';
+
+        zones = {
+          "kun.is" = {
+            master = true;
+            file = kunisZoneFile;
+            allowQuery = [ "any" ];
+          };
+
+          "geokunis2.nl" = {
+            master = true;
+            file = geokunis2nlZoneFile;
+            allowQuery = [ "any" ];
+            slaves = [
+              "87.253.155.96/27"
+              "157.97.168.160/27"
+            ];
+          };
+        };
+      };
+
+      dnsmasq = {
+        enable = true;
+        settings = import ./dnsmasq.nix inputs;
+      };
+    };
+  };
+}

nixos/modules/networking/dmz_services/dnsmasq.nix

@@ -0,0 +1,50 @@
+{ config, ... }:
+let
+  cfg = config.lab.networking;
+in
+{
+  no-resolv = true;
+  local = "/dmz/";
+  dhcp-fqdn = true;
+  no-hosts = true;
+  expand-hosts = true;
+  domain = "dmz";
+  dhcp-authoritative = true;
+  ra-param = "*,0,0";
+  alias = "${cfg.public.ipv4.router},${cfg.dmz.ipv4.dockerSwarm}";
+  log-dhcp = true;
+  log-queries = true;
+  port = "5353";
+  host-record = [
+    "hermes.dmz,${cfg.dmz.ipv4.services},${cfg.dmz.ipv6.services}"
+    "ipv4.hermes.dmz,${cfg.dmz.ipv4.services}"
+    "ipv6.hermes.dmz,${cfg.dmz.ipv6.services}"
+  ];
+
+  server = [
+    cfg.dmz.ipv4.router
+    "/geokunis2.nl/${cfg.dmz.ipv4.services}"
+    "/kun.is/${cfg.dmz.ipv4.services}"
+  ];
+
+  dhcp-range = [
+    "192.168.30.50,192.168.30.127,15m"
+    "2a0d:6e00:1a77:30::,ra-stateless,ra-names"
+  ];
+
+  dhcp-host = [
+    "b8:27:eb:b9:ab:e2,esrom"
+    "ca:fe:c0:ff:ee:08,maestro,${cfg.dmz.ipv4.dockerSwarm}"
+  ];
+
+  dhcp-option = [
+    "3,${cfg.dmz.ipv4.router}"
+    "option:dns-server,${cfg.dmz.ipv4.router}"
+    "option6:dns-server,[2a02:58:19a:30::1]"
+  ];
+
+  address = [
+    "/ns.pizzapim.nl/ns.geokunis2.nl/${cfg.dmz.ipv4.services}"
+    "/ns.pizzapim.nl/ns.geokunis2.nl/${cfg.dmz.ipv6.services}"
+  ];
+}

nixos/modules/networking/dmz_services/zones/geokunis2.nl.nix

@@ -0,0 +1,68 @@
+{ config, dns, ... }:
+with dns.lib.combinators;
+let
+  cfg = config.lab.networking;
+in
+{
+  SOA = {
+    nameServer = "ns";
+    adminEmail = "hostmaster@geokunis2.nl";
+    serial = 2024011401;
+  };
+
+  NS = [
+    "ns.geokunis2.nl."
+    "ns0.transip.net."
+    "ns1.transip.nl."
+    "ns2.transip.eu."
+  ];
+
+  MX = [ (mx.mx 10 "mail.geokunis2.nl.") ];
+
+  A = [ cfg.public.ipv4.router ];
+  AAAA = [ cfg.dmz.ipv6.dockerSwarm ];
+  CAA = letsEncrypt "caa@geokunis2.nl";
+
+  subdomains = {
+    "*" = {
+      A = [ cfg.public.ipv4.router ];
+      AAAA = [ cfg.dmz.ipv6.dockerSwarm ];
+    };
+
+    ns = {
+      A = [ cfg.public.ipv4.router ];
+      AAAA = [ cfg.dmz.ipv6.services ];
+    };
+
+    ns1 = {
+      A = [ cfg.public.ipv4.router ];
+      AAAA = [ cfg.dmz.ipv6.services ];
+    };
+
+    ns2 = {
+      A = [ cfg.public.ipv4.router ];
+      AAAA = [ cfg.dmz.ipv6.services ];
+    };
+
+    # Override because we don't support IPv6 for KMS.
+    kms = {
+      A = [ cfg.public.ipv4.router ];
+      AAAA = [ ];
+    };
+
+    wg = {
+      A = [ cfg.public.ipv4.router ];
+      AAAA = [ cfg.public.ipv6.router ];
+    };
+
+    wg4 = {
+      A = [ cfg.public.ipv4.router ];
+      AAAA = [ ];
+    };
+
+    wg6 = {
+      A = [ ];
+      AAAA = [ cfg.public.ipv6.router ];
+    };
+  };
+}

nixos/modules/networking/dmz_services/zones/kun.is.nix

@@ -0,0 +1,64 @@
+{ config, dns, ... }:
+with dns.lib.combinators;
+let
+  cfg = config.lab.networking;
+in
+{
+  CAA = letsEncrypt "caa@kun.is";
+
+  SOA = {
+    nameServer = "ns1";
+    adminEmail = "webmaster@kun.is";
+    serial = 2024011401;
+  };
+
+  NS = [
+    "ns1.kun.is."
+    "ns2.kun.is."
+  ];
+
+  MX = [
+    (mx.mx 10 "mail.kun.is.")
+  ];
+
+  subdomains = {
+    "*" = {
+      A = [ cfg.public.ipv4.router ];
+      AAAA = [ cfg.dmz.ipv6.dockerSwarm ];
+    };
+
+    ns = {
+      A = [ cfg.public.ipv4.router ];
+      AAAA = [ cfg.dmz.ipv6.services ];
+    };
+
+    ns1 = {
+      A = [ cfg.public.ipv4.router ];
+      AAAA = [ cfg.dmz.ipv6.services ];
+    };
+
+    ns2 = {
+      A = [ cfg.public.ipv4.router ];
+      AAAA = [ cfg.dmz.ipv6.services ];
+    };
+
+    # Override because we don't support IPv6 for Git SSH.
+    git = {
+      A = [ cfg.public.ipv4.router ];
+      AAAA = [ ];
+    };
+
+    # Override because we don't support IPv6 for KMS.
+    kms = {
+      A = [ cfg.public.ipv4.router ];
+      AAAA = [ ];
+    };
+
+    # Override because wg is on opnsense so ipv6 differs from "cfg.dmz.ipv6.services"
+    wg = {
+      A = [ cfg.public.ipv4.router ];
+      AAAA = [ cfg.dmz.ipv6.router ];
+    };
+
+  };
+}