{
  lib,
  config,
  ...
}: let
  cfg = config.lab.storage;
  modules = [
    {
      config = lib.mkIf (cfg.profile == "pi") {
        fileSystems."/" = {
          device = "/dev/disk/by-label/NIXOS_SD";
          fsType = "ext4";
          options = ["noatime"];
        };
      };
    }

    {
      config = lib.mkIf (cfg.profile == "kubernetes") {
        disko.devices = {
          disk = {
            nvme = {
              device = "/dev/nvme0n1";
              type = "disk";

              content = {
                type = "gpt";

                partitions = {
                  boot = {
                    type = "EF00";
                    size = "500M";

                    content = {
                      type = "filesystem";
                      format = "vfat";
                      mountpoint = "/boot";
                    };
                  };

                  pv_os = {
                    size = "79G";

                    content = {
                      type = "lvm_pv";
                      vg = "vg_os";
                    };
                  };

                  pv_nvme_extra = {
                    size = "100%";

                    content = {
                      type = "lvm_pv";
                      vg = "vg_data";
                    };
                  };
                };
              };
            };

            sata = {
              device = "/dev/sda";
              type = "disk";

              content = {
                type = "gpt";

                partitions.pv_sata = {
                  size = "100%";

                  content = {
                    type = "lvm_pv";
                    vg = "vg_data";
                  };
                };
              };
            };
          };

          lvm_vg = {
            vg_os = {
              type = "lvm_vg";

              lvs = {
                root = {
                  size = "75G";

                  content = {
                    type = "filesystem";
                    format = "ext4";
                    mountpoint = "/";
                    mountOptions = ["defaults"];
                  };
                };

                swap = {
                  size = "100%FREE";
                  content.type = "swap";
                };
              };
            };

            vg_data = {
              type = "lvm_vg";

              lvs.longhorn = {
                size = "100%FREE";

                content = {
                  type = "filesystem";
                  format = "xfs";
                  mountpoint = "/mnt/longhorn";
                };
              };
            };
          };
        };
      };
    }

    {
      config = lib.mkIf (cfg.profile == "normal") {
        disko.devices = {
          disk.sata = {
            device = "/dev/sda";
            type = "disk";

            content = {
              type = "gpt";

              partitions = {
                boot = {
                  type = "EF00";
                  size = "500M";

                  content = {
                    type = "filesystem";
                    format = "vfat";
                    mountpoint = "/boot";
                  };
                };

                root = {
                  size = "100%";

                  content = {
                    type = "filesystem";
                    format = "ext4";
                    mountpoint = "/";
                    mountOptions = ["defaults"];
                  };
                };
              };
            };
          };
        };
      };
    }
  ];
in {
  imports = modules;

  options.lab.storage = {
    profile = lib.mkOption {
      type = lib.types.str;
    };
  };
}