Create tesla middleware for adding signature to federation requests

Change repo structure

lib/matrix_server_web/federation/controllers/key_controller.ex

@@ -0,0 +1,36 @@
+defmodule MatrixServerWeb.Federation.KeyController do
+  use MatrixServerWeb, :controller
+
+  import MatrixServerWeb.Error
+
+  alias MatrixServer.KeyServer
+
+  @key_valid_time_ms 1000 * 60 * 24 * 30
+
+  def get_signing_keys(conn, _params) do
+    keys =
+      KeyServer.get_own_signing_keys()
+      |> Enum.into(%{}, fn {key_id, key} ->
+        {key_id, %{"key" => key}}
+      end)
+
+    data = %{
+      server_name: MatrixServer.server_name(),
+      verify_keys: keys,
+      old_verify_keys: %{},
+      valid_until_ts: System.os_time(:millisecond) + @key_valid_time_ms
+    }
+
+    case KeyServer.sign_object(data) do
+      {:ok, sig, key_id} ->
+        signed_data = MatrixServer.add_signature(data, key_id, sig)
+
+        conn
+        |> put_status(200)
+        |> json(signed_data)
+
+      :error ->
+        put_error(conn, :unknown, "Error signing object.")
+    end
+  end
+end

lib/matrix_server_web/federation/controllers/query_controller.ex

@@ -0,0 +1,55 @@
+defmodule MatrixServerWeb.Federation.QueryController do
+  use MatrixServerWeb, :controller
+  use MatrixServerWeb.Federation.AuthenticateServer
+
+  import MatrixServerWeb.Error
+  import Ecto.Query
+
+  alias MatrixServer.{Repo, Account}
+
+  defmodule ProfileRequest do
+    use Ecto.Schema
+
+    import Ecto.Changeset
+
+    @primary_key false
+    embedded_schema do
+      field :user_id, :string
+      field :field, :string
+    end
+
+    def validate(params) do
+      %__MODULE__{}
+      |> cast(params, [:user_id, :field])
+      |> validate_required([:user_id])
+      |> validate_inclusion(:field, ["displayname", "avatar_url"])
+      |> then(fn
+        %Ecto.Changeset{valid?: true} = cs -> {:ok, apply_changes(cs)}
+        _ -> :error
+      end)
+    end
+  end
+
+  def profile(conn, params) do
+    with {:ok, %ProfileRequest{user_id: user_id}} <- ProfileRequest.validate(params) do
+      if MatrixServer.get_domain(user_id) == MatrixServer.server_name() do
+        localpart = MatrixServer.get_localpart(user_id)
+
+        case Repo.one(from a in Account, where: a.localpart == ^localpart) do
+          %Account{} ->
+            # TODO: Return displayname and avatar_url when we implement them.
+            conn
+            |> put_status(200)
+            |> json(%{})
+
+          nil ->
+            put_error(conn, :not_found, "User does not exist.")
+        end
+      else
+        put_error(conn, :not_found, "Wrong server name.")
+      end
+    else
+      _ -> put_error(conn, :bad_json)
+    end
+  end
+end