nixos-configs/home.nix

{ pkgs, lib, config, ... }: {
  imports = [
    ./modules/home-manager/neovim
    ./modules/home-manager/firefox
    ./modules/home-manager/syncthing.nix
    ./modules/home-manager/keepassxc.nix
  ];

  xsession.enable = true;
  xdg.userDirs.enable = true;

  home = {
    username = "pim";
    homeDirectory = "/home/pim";
    stateVersion = "23.05";

    packages = (with pkgs; [
      gnome.gnome-tweaks
      jellyfin-media-player
      virt-manager
    ]) ++ (with pkgs.unstable; [
      attic-client
      dbeaver-bin
      devenv
      bottles-unwrapped
      gimp
      hexchat
      impression
      insomnia
      krita
      libreoffice
      logseq
      moonlight-qt
      nicotine-plus
      qFlipper
      signal-desktop
      strawberry
      telegram-desktop
      vlc
      vorta
      wireshark
    ]);
  };

  programs = {
    home-manager.enable = true;
    chromium.enable = true;
    bat.enable = true;

    alacritty = {
      enable = true;
      settings.shell.program = lib.getExe config.programs.zsh.package;
    };

    thunderbird = {
      enable = true;
      profiles.default.isDefault = true;
    };

    direnv = {
      enable = true;
      enableBashIntegration = true;
      nix-direnv.enable = true;
    };

    fzf = {
      enable = true;
      enableBashIntegration = true;
    };

    zsh = {
      enable = true;
      autocd = true;
      autosuggestion.enable = true;
      prezto.enable = true;
    };

    ssh = {
      enable = true;
      extraConfig = "User root";

      matchBlocks = {
        lewis = lib.hm.dag.entryBefore [ "*" ] { hostname = "lewis.dmz"; };
        atlas = lib.hm.dag.entryBefore [ "*" ] { hostname = "atlas.dmz"; };
        jefke = lib.hm.dag.entryBefore [ "*" ] { hostname = "jefke.dmz"; };
        warwick = lib.hm.dag.entryBefore [ "*" ] { hostname = "warwick.dmz"; };

        github = lib.hm.dag.entryBefore [ "*" ] {
          hostname = "github.com";
          user = "pizzapim";
          identitiesOnly = true;
        };
      };
    };

    git = {
      enable = true;
      userName = "Pim Kunis";
      userEmail = "pim@kunis.nl";

      extraConfig = {
        push.autoSetupRemote = true;
        commit.verbose = true;
        pull.rebase = true;
      };

      includes = [{
        path = "~/git/suecode/.gitconfig";
        condition = "gitdir:~/git/suecode/**";
      }];
    };

    # Currently, it is not possible to have Home Manager manage Liberwolf extensions.
    # There is a draft PR which addresses this:
    # https://github.com/nix-community/home-manager/pull/3339
    # The extensions I currently use are:
    # - ublock-origin (already installed by librewolf)
    # - cookie-autodelete
    # - clearurls
    # - istilldontcareaboutcookies
    # - keepassxc-browser
    # - redirector
    # - violentmonkey
    # - boring-rss
    # - kagi-search
    # - refined-github
    librewolf = {
      enable = true;

      settings = {
        "identity.fxaccounts.enabled" = true;
        "privacy.clearOnShutdown.history" = false;
        "privacy.clearOnShutdown.downloads" = false;
        "browser.translations.automaticallyPopup" = false;
        "browser.aboutConfig.showWarning" = false;
        "privacy.clearOnShutdown.cookies" = false;
      };
    };
  };

  homeage = {
    identityPaths = [ "/home/pim/.ssh/age_ed25519" ];
    installationType = "systemd";
  };

  dconf.settings = with lib.hm.gvariant; {
    "org/gnome/desktop/sound".allow-volume-above-100-percent = true;
    "org.gnome.desktop.wm.preferences".auto-raise = true;

    "org/gnome/shell" = {
      "disable-extension-version-validation" = true;

      enabled-extensions = [
        "workspace-indicator@gnome-shell-extensions.gcampax.github.com"
        "pop-shell@system76.com"
        "windowIsReady_Remover@nunofarruca@gmail.com"
      ];
    };

    "org/gnome/desktop/input-sources" = {
      sources = [ (mkTuple [ "xkb" "us" ]) ];
      xkb-options = [ "terminate:ctrl_alt_bksp" "caps:escape" ];
    };

    "org/gnome/shell/extensions/pop-shell" = {
      active-hint = true;
      fullscreen-launcher = false;
      mouse-cursor-focus-location = mkUint32 4;
      mouse-cursor-follows-active-window = true;
      show-skip-taskbar = false;
      show-title = true;
      smart-gaps = false;
      snap-to-grid = false;
      stacking-with-mouse = true;
      tile-by-default = true;
    };

    "org/gnome/settings-daemon/plugins/media-keys/custom-keybindings/custom0" = {
      binding = "<Super>t";
      command = lib.getExe config.programs.alacritty.package;
      name = "Terminal";
    };

    "org/gnome/settings-daemon/plugins/media-keys/custom-keybindings/custom1" = {
      binding = "<Super>e";
      command = "${lib.getExe config.programs.librewolf.package} --browser";
      name = "Browser";
    };

    "org/gnome/desktop/wm/keybindings" = {
      close = [ "<Shift><Super>q" ];
      minimize = mkEmptyArray type.string;
      move-to-workspace-1 = [ "<Shift> <Super> 1" ];
      move-to-workspace-2 = [ "<Shift><Super>2" ];
      move-to-workspace-3 = [ "<Shift><Super>3" ];
      move-to-workspace-4 = [ "<Shift><Super>4" ];
      switch-applications = mkEmptyArray type.string;
      switch-applications-backward = mkEmptyArray type.string;
      switch-to-workspace-1 = [ "<Super>1" ];
      switch-to-workspace-2 = [ "<Super>2" ];
      switch-to-workspace-3 = [ "<Super>3" ];
      switch-to-workspace-4 = [ "<Super>4" ];
      toggle-fullscreen = [ "<Super>f" ];
    };
  };
}