nixos-laptop/home-manager/default.nix

{ pkgs, lib, config, ... }:

{
  imports = [
    ./bash
    ./neovim
    ./firefox
    ./ssh
    ./syncthing
    ./keepassxc
    ./git
    ./direnv
    ./thunderbird
    ./fzf
    ./bat
  ];

  home = {
    username = "pim";
    homeDirectory = "/home/pim";
    stateVersion = "23.05";

    packages = with pkgs; [
      moonlight-qt
      vlc
      nicotine-plus
      logseq
      signal-desktop
      telegram-desktop
      strawberry
      gimp
      libreoffice
      (pkgs.nerdfonts.override { fonts = [ "Hack" ]; })
      virt-manager
      gnome.gnome-tweaks
    ];
  };

  programs = {
    home-manager.enable = true;
    chromium.enable = true;

    terminator = {
      enable = true;
      config = {
        profiles.default = {
          # Gruvbox theme: https://github.com/egel/terminator-gruvbox
          background_color = "#282828";
          cursor_color = "#7c6f64";
          foreground_color = "#ebdbb2";
          palette = "#181818:#cc241d:#98971a:#d79921:#458588:#b16286:#689d6a:#a89984:#928374:#fb4934:#b8bb26:#fabd2f:#83a598:#d3869b:#8ec07c:#ebdbb2";
        };

        keybindings = {
          zoom_in = "<Ctrl>plus";
          zoom_out = "<Ctrl>minus";
          new_tab = "<Ctrl><Shift>T";
          cycle_next = "<Ctrl>Tab";
          cycle_prev = "<Ctrl><Shift>Tab";
          split_horiz = "<Alt>V";
          split_vert = "<Alt>C";

          go_left = "<Alt>H";
          go_right = "<Alt>L";
          go_up = "<Alt>K";
          go_down = "<Alt>J";

          copy = "<Ctrl><Shift>C";
          paste = "<Ctrl><Shift>V";

          layout_launcher = ""; # Default <Alt>L
        };
      };
    };
  };

  # Let home-manager manage the X session
  xsession = {
    enable = true;
  };

  xdg.userDirs.enable = true;

  homeage = {
    identityPaths = [ "/home/pim/.ssh/age_ed25519" ];
    installationType = "systemd";

    file."common-pg-tfbackend" = {
      source = ../secrets/common-pg-tfbackend.age;
      symlinks = [ "${config.xdg.configHome}/home/common.pg.tfbackend" ];
    };

    file."ansible-vault-secret" = {
      source = ../secrets/ansible-vault-secret.age;
      symlinks = [ "${config.xdg.configHome}/home/ansible-vault-secret" ];
    };

    file."powerdns-api-key" = {
      source = ../secrets/powerdns-api-key.json.age;
      symlinks = [ "${config.xdg.configHome}/home/powerdns-api-key.json" ];
    };
  };

  fonts.fontconfig.enable = true;

  dconf.settings = with lib.hm.gvariant; {
    "org/gnome/desktop/input-sources" = {
      sources = [ (mkTuple [ "xkb" "us" ]) ];
      xkb-options = [ "terminate:ctrl_alt_bksp" "caps:escape" ];
    };

    "org/gnome/desktop/interface" = {
      monospace-font-name = "Hack Nerd Font Mono 10";
    };
  };
}